Next / Previous / Contents / NM Tech homepage

7.3.3. The footer.navigation template

This template replaces the stock footer.navigation template from html/chunk-common.xsl. It takes the same three parameters as the ones passed to Section 7.3.1, “The header.navigation template”. It has the same two internal variables: home, the article node of the document; and up, the parent node.

zdp_html.xsl
<!--footer.navigation: Bottom-of-page navigational links-->
<xsl:template name="footer.navigation">
  <xsl:param name="prev" select="/foo"/>
  <xsl:param name="next" select="/foo"/>
  <xsl:param name="nav.context"/>

  <xsl:variable name="home" select="/*[1]"/>
  <xsl:variable name="up" select="parent::*"/>

First we output a horizontal rule to set off the page body from the footer content.

zdp_html.xsl
  <hr/>

The content of the footer is enclosed in a div element, with class="navfooter" so that we can apply a CSS rule to just this div.

zdp_html.xsl
  <!--Navigational links at the page bottom-->
  <div class="navfooter">

The standard page-bottom links are output by a separate template; see Section 7.3.4, “The bot.links template”.

zdp_html.xsl
    <xsl:call-template name="bot.links">
      <xsl:with-param name="prev" select="$prev"/>
      <xsl:with-param name="next" select="$next"/>
      <xsl:with-param name="home" select="$home"/>
    </xsl:call-template>

The colophon, or author credit information, is output by yet another template; see Section 7.3.5, “The zdp.colophon template”.

zdp_html.xsl
    <!--Colophon: Author credit, timestamp, and URL-->
    <xsl:call-template name="zdp.colophon">
      <xsl:with-param name="home" select="$home"/>
    </xsl:call-template>
  </div>
</xsl:template>