Customization of the 4.3 DocBook-XSL Stylesheets for the TCC

By default, the header area on each page is set off from the content with a ruled line. Because the TCC style does not use a running head, we turn off header.rule to eliminate this rule.

<xsl:param name="header.rule" select="0"/>

The stock header.content template is in fo/pagesetup.xsl; this template generates the content of the running head. We replace that here with one that has no content.

<xsl:template name="header.content">
  <xsl:param name="pageclass" select="''"/>
  <xsl:param name="sequence" select="''"/>
  <xsl:param name="position" select="''"/>
  <xsl:param name="gentext-key" select="''"/>
</xsl:template>

Footer customization is discussed at length in Chapter 12 of Stayton under the heading “Running headers and footers.”

First we change the appearance of the text in the running footer to make it look different from the body text. This is specified by the footer.content.properties attribute set; the stock version is in fo/param.xsl. The TCC Documentation Plan mandates nine-point italic text.

<xsl:attribute-set name="footer.content.properties">
  <xsl:attribute name="font-style">italic</xsl:attribute>
  <xsl:attribute name="font-size">9pt</xsl:attribute>

The rest of this attribute set is from the stock version.

  <xsl:attribute name="font-family">
    <xsl:value-of select="$body.fontset"/>
  </xsl:attribute>
  <xsl:attribute name="margin-left">
    <xsl:value-of select="$title.margin.left"/>
  </xsl:attribute>
</xsl:attribute-set>

The footer is formatted as a one-row, three-column table. The footer's content depends on two variables:

In our format, the content of the three columns of the footer table is shown by this table. The “Case” column describes which case applies, and the three cells of the footer table are called left, center, and right.

This layout puts the page number in the center of single-sided pages, the outside of double-sided pages.

So, here's the footer.content template. It is called once for each of the three different footer positions, and returns the content that should go in that position. It takes four parameters: pageclass, sequence, and position are described above. The gentext-key parameter is not used; its function is discussed on p. 195 of Stayton.

<xsl:template name="footer.content">
  <xsl:param name="pageclass" select="''"/>
  <xsl:param name="sequence" select="''"/>
  <xsl:param name="position" select="''"/>
  <xsl:param name="gentext-key" select="''"/>

The entire footer content is wrapped in a block container.

  <fo:block>

First we eliminate the titlepage case: there is no footer on title pages. (The current article style has no separate title page, if you're wondering how come all the TCC documents have a running footer on the first page.)

    <xsl:choose>
      <xsl:when test="$pageclass = 'titlepage'">
        <!--no footer on title pages-->
      </xsl:when>

For non-title pages, the next important case is single-sided output.

      <xsl:otherwise>       <!--Not a title page-->
        <xsl:choose>
          <xsl:when test="$double.sided = 0">   <!-- Single-sided -->
            <xsl:choose>
              <xsl:when test="$position = 'left'">
                <xsl:apply-templates select="."
                    mode="titleabbrev.markup"/>
              </xsl:when>
              <xsl:when test="$position = 'center'">
                <fo:page-number/>
              </xsl:when>
              <xsl:when test="$position = 'right'">
                <xsl:text>New Mexico Tech Computer Center</xsl:text>
              </xsl:when>
            </xsl:choose>
          </xsl:when>       <!-- Single-sided -->

The titleabbrev.markup mode selects a titleabbrev if there is one, defaulting to the document's title.

The remaining cases are for the two double-sided formats. First, the left position, which is the logo for odd pages and the page number for even pages.

          <xsl:otherwise>   <!--Double-sided--> 
            <xsl:choose>
              <xsl:when test="$position = 'left'">
                <xsl:choose>
                  <xsl:when test="$sequence = 'even' or
                                  $sequence = 'blank'">
                    <fo:page-number/>
                  </xsl:when>
                  <xsl:otherwise> <!-- left/odd -->
                    <xsl:text>New Mexico Tech Computer Center</xsl:text>
                  </xsl:otherwise>
                </xsl:choose>
              </xsl:when>

The center position always contains the running title.

              <xsl:when test="$position = 'center'">
                <xsl:apply-templates select="." mode="titleabbrev.markup"/>
              </xsl:when>

The right position on a double-sided page contains the folio on odd pages, the logo on even pages.

              <xsl:when test="$position = 'right'">
                <xsl:choose>
                  <xsl:when test="$sequence = 'even' or
                                  $sequence = 'blank'">
                    <xsl:text>New Mexico Tech Computer Center</xsl:text>
                  </xsl:when>
                  <xsl:otherwise> <!-- left/odd -->
                    <fo:page-number/>
                  </xsl:otherwise>
                </xsl:choose>
              </xsl:when>
            </xsl:choose>
          </xsl:otherwise>  <!-- Double-sided -->
        </xsl:choose>
      </xsl:otherwise>      <!--Not a title page-->
    </xsl:choose>
  </fo:block>
</xsl:template>