Customization of the 4.3 DocBook XSL Stylesheets for the TCC

The colophon section contains:

The template takes one parameter, home, the article node. It needs that to generate the “Contents” link.

<xsl:template name="tcc.colophon">
  <xsl:param name="home"/>

First comes the horizontal rule, then the start of a div element with class="colophon" so we can write CSS rules for this section, then the start of the address element.

  <hr/>
  <div class="colophon">
    <address>

To generate all the author names, we call a separate template; see Section 6.3.6, “The author.colophon.mode template”.

      <xsl:apply-templates select="$home/articleinfo/authorgroup"
        mode="author.colophon.mode"/>

The mailto: link forwards mail to tcc-doc@nmt.edu, which is the mailing alias for the TCC Documentation Group. This ends the HTML address element.

      <div class="colophon-mailto">
        <xsl:text>Comments welcome: </xsl:text>
        <a href="mailto:tcc-doc@nmt.edu">tcc-doc@nmt.edu</a>
      </div>
    </address>

The “Last updated” line is wrapped in a div to put it on a separate line. The datetime.format template is located in common/pi.xsl. It uses the EXSLT extension module http://exslt.org/dates-and-times; see the online documentation for dates-and-times.

    <div class="colophon-date">
      <xsl:text>Last updated: </xsl:text>
      <xsl:call-template name="datetime.format">
        <xsl:with-param name="date" select="date:date-time()"/>
        <xsl:with-param name="format" select="'Y-m-d H:M'"/>
      </xsl:call-template>
    </div>

We use Server Side Includes to generate the page's own URL; see Using HTML Server Side Includes (SSI). SSI commands are syntactically represented as comments whose first character is "#". The echo command causes insertion of some variable's value into the web page, and the DOCUMENT_URI variable is always the URL of the web page itself.

    <div class="colophon-url">
      <xsl:text>URL: </xsl:text>
      <span class="colophon-uri">
        <xsl:text>http://www.nmt.edu</xsl:text>
        <xsl:comment>#echo var="DOCUMENT_URI"</xsl:comment>
      </span>
    </div>
  </div>
</xsl:template>